Meeting Pearls 4/Meeting Pearls Vol. IV (1996)(GTI - Schatztruhe)[!].iso/sys/s/CopyToHD

AmigaDOS Script File | 1996-10-20 | 6KB | 164 lines

.key FROM/A,TO/A,MPUSEMETATOOL/S,USEMETATOOL/S,COPYDRAWERANDICON/S,LANGUAGE
.bra {
.ket }


IF NOT EXISTS ":{FROM}"
    IF {LANGUAGE} EQ "deutsch"
        :C/AutoReq "-tInterner Fehler:" "-tVerzeichnis »{FROM}«" "-texistiert nicht." -nOK
    ELSE
        :C/AutoReq "-tInternal error:" "-tDrawer »{FROM}«" "-tdoes not exist." -nOK
    ENDIF
    QUIT 20
ENDIF


FailAt 25

IF {LANGUAGE} EQ "deutsch"
    :C/WaitingReq ON "MPWAITINGREQ{$$}" "*nKopier-Operation wird gestartet*nQuelle: {FROM}*nZiel: {TO}*n*n" CON:0/30/640/140/INFO
ELSE
    :C/WaitingReq ON "MPWAITINGREQ{$$}" "*nCopy command in process*nSource: {FROM}*nDestination: {TO}*n*n" CON:0/30/640/140/INFO
ENDIF

IF "{MPUSEMETATOOL}" EQ "MPUSEMETATOOL"
    Skip UseMetaTool
ENDIF

IF "{USEMETATOOL}" EQ "USEMETATOOL"
    Skip UseMetaTool
ENDIF

Skip NoMetaTool

LAB UseMetaTool
IF NOT EXISTS ENV:METACONFIG
    :C/Version >NIL: 37
    IF WARN
        Copy :MetaTool/MetaTool33.config-HD S:
        SetEnv METACONFIG S:MetaTool33.config-HD
        IF {LANGUAGE} EQ "deutsch"
            :C/WaitingReq UPDATE "MPWAITINGREQ{$$}" "Bitte passen Sie die Datei S:MetaTool33.config-HD an Ihr System an.*n*n"
        ELSE
            :C/WaitingReq UPDATE "MPWAITINGREQ{$$}" "Please edit the file S:MetaTool33.config-HD to fit in your system.*n*n"
        ENDIF
        IF EXISTS ENV:EDITOR
            "$EDITOR" S:MetaTool33.config-HD
        ENDIF
    ELSE
        :C/Version >NIL: 39
        IF WARN
            Copy :MetaTool/MetaTool37.config-HD S:
            SetEnv METACONFIG S:MetaTool37.config-HD
            IF {LANGUAGE} EQ "deutsch"
                :C/WaitingReq UPDATE "MPWAITINGREQ{$$}" "Bitte passen Sie die Datei S:MetaTool37.config-HD an Ihr System an.*n*n"
            ELSE
                :C/WaitingReq UPDATE "MPWAITINGREQ{$$}" "Please edit the file S:MetaTool37.config-HD to fit in your system.*n*n"
            ENDIF
            IF EXISTS ENV:EDITOR
                "$EDITOR" S:MetaTool37.config-HD
            ENDIF
        ELSE
            Copy :MetaTool/MetaTool39.config-HD S:
            SetEnv METACONFIG S:MetaTool39.config-HD
            IF {LANGUAGE} EQ "deutsch"
                :C/WaitingReq UPDATE "MPWAITINGREQ{$$}" "Bitte passen Sie die Datei S:MetaTool39.config-HD an Ihr System an.*n*n"
            ELSE
                :C/WaitingReq UPDATE "MPWAITINGREQ{$$}" "Please edit the file S:MetaTool39.config-HD to fit in your system.*n*n"
            ENDIF
            IF EXISTS ENV:EDITOR
                "$EDITOR" S:MetaTool39.config-HD
            ENDIF
        ENDIF
    ENDIF
    Copy ENV:METACONFIG ENVARC:
ENDIF

LAB NoMetaTool

Assign MPTMPCOPYDIR{$$}: ":"
IF "{COPYDRAWERANDICON}" EQ "COPYDRAWERANDICON"
    Copy FROM "MPTMPCOPYDIR{$$}:{FROM}(%|.info)" TO "{TO}" ALL QUIET CLONE
    MPTMPCOPYDIR{$$}:C/MPGetDestPath >ENV:MPNEWPATH "{FROM}" "{TO}"
    MPTMPCOPYDIR{$$}:C/icontools unsnapshot "$MPNEWPATH.info"
    CD "$MPNEWPATH"
    Delete ENV:MPNEWPATH QUIET
ELSE
    Copy FROM "MPTMPCOPYDIR{$$}:{FROM}" TO "{TO}" ALL QUIET CLONE
    MPTMPCOPYDIR{$$}:C/icontools unsnapshot "{TO}.info"
    CD "{TO}"
ENDIF

IF {LANGUAGE} EQ "deutsch"
    MPTMPCOPYDIR{$$}:C/WaitingReq UPDATE "MPWAITINGREQ{$$}" "Attribute und Kommentare werden angepaßt*n*n"
ELSE
    MPTMPCOPYDIR{$$}:C/WaitingReq UPDATE "MPWAITINGREQ{$$}" "Restoring protection flags and file comments*n*n"
ENDIF

List >ENV:MPTMPSADVAR{$$} MPTMPCOPYDIR{$$}:SYS/T/Test LFORMAT "%a%c"
IF $MPTMPSADVAR{$$} EQ "-sp-r--dTest-Kommentar"
    IF {LANGUAGE} EQ "deutsch"
        MPTMPCOPYDIR{$$}:C/WaitingReq UPDATE "MPWAITINGREQ{$$}" "=> Oops, das ist auf ihrem System gar nicht nötig!*n   Sie benutzen wohl ein CD-ROM Dateisystem, das Amiga-Protectionbits unterstützt.*n   Mehr Informationen unter :Pearls/cdrom/MakeCD.*n*n"
    ELSE
        MPTMPCOPYDIR{$$}:C/WaitingReq UPDATE "MPWAITINGREQ{$$}" "=> Oops, this is not necessary on your system!*n   You probably use a CD-ROM filesystem, that supports Amiga protection bits.*n   For more information refer to :Pearls/cdrom/MakeCD.*n*n"
    ENDIF
ELSE
    Resident MPTMPCOPYDIR{$$}:C/SetComment PURE ADD
    Resident MPTMPCOPYDIR{$$}:C/SetProtection PURE ADD
    Execute "MPTMPCOPYDIR{$$}:SetAttributesDir/{FROM}/SetAttributes" "MPTMPCOPYDIR{$$}:SetAttributesDir/{FROM}"
    Resident SetComment REMOVE
    Resident SetProtection REMOVE
ENDIF
Delete ENV:MPTMPSADVAR{$$}

IF {LANGUAGE} EQ "deutsch"
    MPTMPCOPYDIR{$$}:C/WaitingReq UPDATE "MPWAITINGREQ{$$}" "Default-Tools werden angepaßt*n*n"
ELSE
    MPTMPCOPYDIR{$$}:C/WaitingReq UPDATE "MPWAITINGREQ{$$}" "Restoring default tools*n*n"
ENDIF

Echo  >RAM:CPTOHDIT{$$} "TEXT"
Echo >>RAM:CPTOHDIT{$$} "$FPMTTEXT"
Echo >>RAM:CPTOHDIT{$$} "GUIDE"
Echo >>RAM:CPTOHDIT{$$} "$FPMTGUIDE"
Echo >>RAM:CPTOHDIT{$$} "INST"
Echo >>RAM:CPTOHDIT{$$} "$FPMTINST"
Echo >>RAM:CPTOHDIT{$$} "ICONX"
Echo >>RAM:CPTOHDIT{$$} "$FPMTICONX"
Echo >>RAM:CPTOHDIT{$$} "HTML"
Echo >>RAM:CPTOHDIT{$$} "$FPMTHTML"
Echo >>RAM:CPTOHDIT{$$} "BIN"
Echo >>RAM:CPTOHDIT{$$} "$FPMTBIN"
Echo >>RAM:CPTOHDIT{$$} "REXX"
Echo >>RAM:CPTOHDIT{$$} "$FPMTREXX"
Echo >>RAM:CPTOHDIT{$$} "PS"
Echo >>RAM:CPTOHDIT{$$} "$FPMTPS"
Echo >>RAM:CPTOHDIT{$$} "8SVX"
Echo >>RAM:CPTOHDIT{$$} "$FPMT8SVX"
Echo >>RAM:CPTOHDIT{$$} "MOD"
Echo >>RAM:CPTOHDIT{$$} "$FPMTMOD"
Echo >>RAM:CPTOHDIT{$$} "JPEG"
Echo >>RAM:CPTOHDIT{$$} "$FPMTJPEG"
Echo >>RAM:CPTOHDIT{$$} "GIF"
Echo >>RAM:CPTOHDIT{$$} "$FPMTGIF"
Echo >>RAM:CPTOHDIT{$$} "ILBM"
Echo >>RAM:CPTOHDIT{$$} "$FPMTILBM"
Echo >>RAM:CPTOHDIT{$$} "MOVIE"
Echo >>RAM:CPTOHDIT{$$} "$FPMTMOVIE"
Echo >>RAM:CPTOHDIT{$$} "ANIM"
Echo >>RAM:CPTOHDIT{$$} "$FPMTANIM"
Echo >>RAM:CPTOHDIT{$$} "DVI"
Echo >>RAM:CPTOHDIT{$$} "$FPMTDVI"
Echo >>RAM:CPTOHDIT{$$} "TEX"
Echo >>RAM:CPTOHDIT{$$} "$FPMTTEX"
Echo >>RAM:CPTOHDIT{$$} "SOURCE"
Echo >>RAM:CPTOHDIT{$$} "$FPMTSOURCE"

MPTMPCOPYDIR{$$}:C/icontools replace_mp_file "" RAM:CPTOHDIT{$$} recursive

MPTMPCOPYDIR{$$}:C/WaitingReq OFF "MPWAITINGREQ{$$}"
Delete QUIET RAM:CPTOHDIT{$$}

CD MPTMPCOPYDIR{$$}:
Assign MPTMPCOPYDIR{$$}: